Fr:Fonctions de Texte dans Calc

From NeoWiki

Jump to: navigation, search

Certaines des fonctions de texte sont bien décrites dans l'aide (choisissez le menu Aide > NeoOffice aide > NeoOffice Calc et entrez Fonctions dans le champ de recherche). Mais d'autres sont plus délicates à utiliser. Cet article en donne quelques exemples.

Contents

Remarque préliminaire

Vous ne pouvez pas, pour modifier une cellule, lui appliquer une fonction qui lui fasse référence.

Exemple

Si vous voulez mettre en majuscule le texte contenu dans la cellule A1, vous ne pouvez pas cliquer dans A1 et entrer dans la barre de formule =MAJUSCULE(A1). Il faut sélectionner une cellule intermédiaire, B1 par exemple, entrer la formule précédente dans B1, presser la touche Retour. Puis vous devez copier la cellule B1 (Cmd-C ou couper Cmd-X), cliquer dans A1, et aller dans le menu Édition, choisir Collage spécial…, ou presser les touches Maj-Cmd-V. Dans la fenêtre de dialogue qui s'ouvre, décochez Insérer tout ainsi que Formules .

Fonction SUBSTITUE

Remplace une chaine de texte par une autre; elle utilise la fonction NBCAR qui renvoie le nombre de caractères dans une cellule. Elle prend quatre paramètres : le texte dans lequel doit s'effectuer la substitution, le texte à remplacer, le texte de remplacement et l'occurrence qui doit être remplacée. Si aucune occurence n'est spécifiée, toutes les occurrences sont remplacées.

Exemples

La cellule A1 contient le texte "sessions de juin 2000, septembre 2000 et juin 2002"

=SUBSTITUE(A1;"2000";"2001") remplace "sessions de juin 2000, septembre 2000 et juin 2002" par "sessions de juin 2001, septembre 2001 et juin 2002".
=SUBSTITUE(A1;"2000";"2001";2) remplace "sessions de juin 2000, septembre 2000 et juin 2002" par "sessions de juin 2000, septembre 2001 et juin 2002".

Compter le nombre d'occurrences d'un caractère dans une cellule, par exemple de la lettre "a" dans la cellule A1:

=NBCAR(A1)-NBCAR(SUBSTITUE(A1;"a";""))

Vous obtenez seulement le nombre fois où "a" apparait en minuscule. Si vous voulez compter le nombre d'occurrences de cette lettre en minuscule et en majuscule, vous devez entrer :

=NBCAR(A1)-NBCAR(SUBSTITUE(A1;"a";""))+(NBCAR(A1)-NBCAR(SUBSTITUE(A1;"A";"")))

Fonction REMPLACER

Elle remplace aussi une chaine de caractères par une autre, mais ses paramètres sont différents de ceux de la fonction SUBSTITUE. Ce sont : le texte dans lequel s'effectue le remplacement, la position à partir de laquelle s'effectue le remplacement, la longueur du texte à remplacer et le texte de remplacement.

Note : Si vous appliquez les fonctions SUBSTITUE ou REMPLACER à un nombre, le résultat sera en format texte. Vous devrez le reconvertir en format numérique, en utilisant la fonction CNUM.

=CNUM(REMPLACER(1115693;2;2;365))

donne le nombre 13655693.


Fonction CONCATENER

Elle assemble deux ou plusieurs chaines de texte. Elle est facile à utiliser, mais soyez attentif au fait suivant : si l'un des textes est trop long (à partir de 243 caractères), un message d'erreur s'affiche. Il faut alors couper ce texte en deux (ou plus selon sa longueur) et concaténer les parties ainsi obtenues.

Fonctions CHERCHE et TROUVE

Ces deux fonctions cherchent un texte dans le contenu d'une cellule. Les différences entre les deux sont les suivantes : CHERCHE ne tient pas compte de la casse et prend en charge les expressions régulières (voir ci-dessous l'exemple dans la section Fonction DROITE), TROUVE tient compte de la casse, mais ne prend pas en charge les expressions régulières.

Fonction GAUCHE

Elle renvoie le ou les premiers caractères d'un texte, en prenant comme paramètres ce texte et le nombre de caractères à renvoyer.

Exemple : chercher le premier mot du texte contenu dans la cellule A1. Entrez
=GAUCHE(A1;CHERCHE(" ";A1)-1)

Note : Si vous entrez =GAUCHE(A1;CHERCHE(" ";A1)), vous obtenez le premier mot et l'espace qui suit.

Fonction DROITE

Elle renvoie les derniers caractères d'un texte, en prenant comme paramètres ce texte et le nombre de caractères situés à gauche. Elle est délicate à utiliser, car le nombre de caractères situés à gauche n'est pas toujours facile à déterminer. Par exemple, si vous voulez trouver le dernier mot d'un texte, vous ne savez pas, en général, à quel niveau il se trouve. Pour résoudre ce problème, il faut utiliser la fonction CHERCHE avec les expressions régulières.

La formule
=DROITE(A1;NBCAR(A1)-CHERCHE(" [a-zàâçèéêîïôùæœ]+$";A1)) renvoie le dernier mot de la cellule. N'oubliez pas les guillemets et l'espace qui précède [a-zàâçèéêîïôùæœ]+$.
Si vous devez prendre en compte des nombres, il faut entrer :

=DROITE(A1;NBCAR(A1)-CHERCHE(" [a-zàâçèéêîïôùæœ0-9]+$";A1))

Liens dans NeoWiki

Vous pouvez consulter la page Décomposer des noms dans NeoOffice Calc pour voir une application de ces fonctions.


Cet article dans d'autres langues : English
Retrieved from "https://neowiki.neooffice.org/index.php/Fr:Fonctions_de_Texte_dans_Calc"
Personal tools